Misc

Решил начать цикл статей по ассемблеру, и, в частности, по MASM32. Пригодятся эти мануалы с примерами тем, кто хочет поднять свои навыки программирования и развить умение программировать на ассемблере. Пакет MASM32 - это не просто голый ассемблер. В нём есть огромное множество облегчающих разработку софта вещей - пользовательские макросы, встроенные функции и макросы, дебаггер и прочее, и обо всём этом я буду рассказывать. Конечно, читать такие статьи будет гораздо легче тем, кто уже умеет программировать на каком-нибудь языке. Если вы программируете на каком-нибудь говне вроде Visual Basic, или фанатеете от перетаскивания компонентов и кнопочек на формы в дельфи или Borland C++ - не расстраивайтесь, я расскажу, как можно перетаскивать кнопочки и в ассемблере. Разумеется, никаких стандартных облегчающих жизнь компонентов здесь не будет, но это побудит разобраться с WinAPI - огромной кладезью полезных функций, которые способны делать всё, начиная от чтения данных из сокета и заканчивая отображением окон.

Собственно, эту статью я начну с примера простого GUI-приложения на MASM. Конечно, проектировать дизайн окна мы будем визуально (я же обещал). Для этого сначала следует скачать визуальный редактор ресурсов ResEd. Запускаем его и видим интерфейс:

Создаем новый файл ресурсов (File - New Project и вводим имя). В правой верхней панели появляется значок папки и имя файла. Кликаем по ней правой кнопкой и нажимаем "Add Dialog". Теперь мы можем визуально спроектировать интерфейс окна и изменить его настройки. Я создал простое окно TEST_DIALOG с двумя кнопками TEST_BTN и EXIT_BTN:

Если вы успели обрадоваться - не спешите: здесь нельзя программировать, можно только делать дизайн интерфейса. Теперь необходимо добавить в наш файл ресурсов еще пару вещей. Первое - это include-файл с определениями всех констант, который будет необходим компилятору ресурсов MASM32. Как и раньше, нажимаем правой кнопкой мыши по значку папки, выбираем "Include file", "Add" и вводим путь. У меня это C:\masm32\include\RESOURCE.H. У вас может быть и другой, зависит от папки установки masm32 (как? вы еще не установили его?).

Теперь еще одна вещь. Пусть наше окно и кнопки выглядят в современном XP-стиле. Для этого необходимо добавить к файлу ресурсов XP Manifest. Добавляется он аналогично предыдущим пунктам (Add XP Manifest).

Теперь сохраняем файл ресурсов. Он должен выглядеть примерно таким образом:

#define MANIFEST 24
#define TEST_DIALOG 1000
#define TEST_BTN 1001
#define EXIT_BTN 1002
#define IDR_XPMANIFEST1 1
 
#include "C:/masm32/include/RESOURCE.H"
 
TEST_DIALOG DIALOGEX 6,6,134,51
CAPTION "Test Dialog"
FONT 8,"MS Sans Serif",0,0,0
STYLE WS_VISIBLE|WS_CAPTION|WS_SYSMENU
BEGIN
  CONTROL "Тест",TEST_BTN,"Button",WS_CHILD|WS_VISIBLE|WS_TABSTOP,6,18,54,13
  CONTROL "Выход",EXIT_BTN,"Button",WS_CHILD|WS_VISIBLE|WS_TABSTOP,72,18,54,13
END
 
IDR_XPMANIFEST1 MANIFEST "xpmanifest.xml"

Осталось написать программу. Я в качестве редактора предпочитаю обычный Блокнот Windows. Сначала я приведу полный листинг, а потом прокомментирую его построчно:

.386
.model flat, stdcall
option casemap :none
 
include \masm32\include\windows.inc
include \masm32\macros\macros.asm
uselib kernel32, user32, masm32, comctl32
 
WndProc PROTO :DWORD,:DWORD,:DWORD,:DWORD
 
TEST_DIALOG = 1000
TEST_BTN = 1001
EXIT_BTN = 1002
 
.data?
  hInstance dd ?
  hWnd dd ?
  icce INITCOMMONCONTROLSEX <>
 
.code
  start:
    mov icce.dwSize, SIZEOF INITCOMMONCONTROLSEX
    mov icce.dwICC, ICC_DATE_CLASSES or \
                    ICC_INTERNET_CLASSES or \
                    ICC_PAGESCROLLER_CLASS or \
                    ICC_COOL_CLASSES
 
    invoke InitCommonControlsEx, offset icce
 
    invoke GetModuleHandle, NULL
    mov hInstance, eax
 
    invoke DialogBoxParam, hInstance, TEST_DIALOG, 0, offset WndProc, 0
 
    invoke ExitProcess,eax
 
WndProc proc hWin :DWORD, uMsg :DWORD, wParam :DWORD, lParam :DWORD
  switch uMsg
    case WM_INITDIALOG
      invoke SendMessage, hWin, WM_SETICON, 1, FUNC(LoadIcon, NULL, IDI_ASTERISK)
 
    case WM_COMMAND
      switch wParam
        case TEST_BTN
          invoke MessageBox, hWin, chr$("Hello, world!"), chr$("Test"), 0
        case EXIT_BTN
          jmp exit_program
      endsw
    case WM_CLOSE
      exit_program:
      invoke EndDialog, hWin, 0
 
    endsw
 
  xor eax,eax
ret
WndProc ENDP
 
end start

Итак, начнем:

.386
.model flat, stdcall
option casemap :none

Эти директивы говорят о том, что мы пишем код под 386 архитектуру процессора (это так и будет всегда), вторая говорит о том, что модель памяти мы используем плоскую и вызовы функций по стандарту stdcall. Этот стандарт подразумевает, что аргументы функциям передаются через стек в обратном порядке, и функция сама должна удалять их оттуда. Кроме того, функции сохраняют регистры ebx, edi и esi и возвращают значение в регистре eax. Если вы сейчас ничерта не поняли - не расстраивайтесь, это всё прекрасно разъяснено в гугле - и про регистры, и про стек. Если вы занимаетесь программированием, то понять это не составит труда.

include \masm32\include\windows.inc
include \masm32\macros\macros.asm
uselib kernel32, user32, masm32, comctl32

Здесь мы подключаем необходимые библиотеки. kernel32 содержит функцию ExitProcess, user32 - всякие GUI-функции, comctl32 - функции работы с common controls, masm32 - библиотека встроенных функций masm32, я не знаю, зачем я ее здесь подключил, потому что она все равно в этом простом проекте не используется. Ну, лишнего объема, как в дельфи, это не добавит, если функции из библиотеки не используются. Я расскажу о ней в будущем. uselib - это макрос masm32, который всё необходимое позволяет одной строкой подключить. Только представьте, эти три строки эквивалентны следующему коду:

include \masm32\include\windows.inc
include \masm32\macros\macros.asm
 
include \masm32\include\user32.inc
include \masm32\include\kernel32.inc
include \masm32\include\masm32.inc
include \masm32\include\comctl32.inc
 
includelib \masm32\lib\user32.lib
includelib \masm32\lib\kernel32.lib
includelib \masm32\lib\masm32.lib
includelib \masm32\lib\comctl32.lib

Как узнать, из какой библиотеки функция? Смотреть msdn.

Идем дальше...

WndProc PROTO :DWORD,:DWORD,:DWORD,:DWORD

Эта строка представляет собой прототип процедуры. Если вы программируете на C или C++, то знаете, что это такое, если нет - я поясню. Функцию нельзя вызывать до того, как она будет объявлена, поэтому в начало файла часто пишутся прототипы функций, расположенных в других файлах или ниже места первого вызова функции.

TEST_DIALOG = 1000
TEST_BTN = 1001
EXIT_BTN = 1002

Этими строками мы просто объявили некоторые значения из нашего файла ресурсов new.rc. Можно было бы этого и не делать, но с ними программа будет более читаемой.

.data?
  hInstance dd ?
  icce INITCOMMONCONTROLSEX <>

В этом куске кода у нас объявляются глобальные переменные в секции неинициализированных данных. Что это такое? Это просто переменные, не имеющие начального значения. Они не занимают места в получающемся после компиляции exe-файле. В hInstance мы будем хранить указатель на модуль нашей программы (зачем - позже поясню), а в icce - структуру INITCOMMONCONTROLSEX (также объясню позже). dd - он же DWORD - тип данных "двойное слово". В C++ такой тип имеют int, long и все указатели, но C и C++ являются более типизированными языками, а в ассемблере всё сводится к двойным словам (4 байта).

Чтобы объявить секцию инициализированных данных и глобальные переменные в ней, пишут так:

.data
  vasya dd 0
  some_string db "hello, world", 0 ;строковая переменная, состоящая из db - байтов (он же BYTE)

В нашей программе тоже будет секция инициализированных данных, просто она неявно объявляется, далее я расскажу об этом.

.code
  start:
    mov icce.dwSize, SIZEOF INITCOMMONCONTROLSEX
    mov icce.dwICC, ICC_DATE_CLASSES or \
                    ICC_INTERNET_CLASSES or \
                    ICC_PAGESCROLLER_CLASS or \
                    ICC_COOL_CLASSES
 
    invoke InitCommonControlsEx, offset icce
 
    invoke GetModuleHandle, NULL
    mov hInstance, eax
 
    invoke DialogBoxParam, hInstance, TEST_DIALOG, 0, offset WndProc, 0
 
    invoke ExitProcess, eax

Что же происходит здесь? Здесь мы уже объявляем секцию исполняемого кода и метку start, которую потом объявим точкой входа.
Мы инициализируем объявленную ранее структуру icce и вызываем функцию InitCommonControlsEx. Инструкция mov загружает данные в регистр или ячейку памяти. Представьте, что мы пишем

    icce.dwSize = SIZEOF(INITCOMMONCONTROLSEX);
    icce.dwICC = ICC_DATE_CLASSES |
                    ICC_INTERNET_CLASSES |
                    ICC_PAGESCROLLER_CLASS |
                    ICC_COOL_CLASSES;
 
    InitCommonControlsEx(&icce);

... и всё станет понятнее. Встроенный макрос invoke используется для вызовы любых функций, у которых есть прототип (а прототипы всех WinAPI прописаны в заголовочных файлах MASM32, которые мы подключили в самом начале программы). Sizeof возвращает размер структуры в байтах, offset позволяет получить смещение в памяти какого-либо байта. Есть еще addr, позволяющая получить смещение какого-то байта, размещенного в памяти по заранее неизвестному адресу (например, для локальных переменных в процедурах).

Теперь дальше - мы получаем указатель на начало нашего исполняемого модуля. Опять-таки, представьте, что мы пишем

    hInstance = GetModuleHandle(NULL);

Все stdcall-функции возвращают значение в регистре eax, как я уже говорил, а GetModuleHandle как раз stdcall WinAPI. Ах да, у вас, вероятно, есть вопросы по этим функциям, если вы впервые слышите про WinAPI? Ну так вбейте название непонятной функции в гугл, и получите ссылку на msdn с подробнейшим описанием.

И, как вы уже могли догадаться, мы создаем диалоговое окно функцией DialogBoxParam с указанием идентификатора диалога из файла ресурса (TEST_DIALOG = 1000). Эта функция начинает цикл сообщений windows с использованием функции WndProc, на которую мы передали указатель. Это типизированная функция, далее я опишу ее, но пока что - пара слов о цикле сообщений. Каждое окно в Windows получает множество сообщений от системы или других приложений, от других окон или от своего же в непрерывном цикле. Процедура WndProc будет эти сообщения получать, а мы будем в ней обрабатывать часть сообщений. которые нужны нам.

Далее я распишу код с комментариями:

;WndProc - это процедура, которая принимает 4 параметра
;hWin - хендл окна, которому передается сообщение
;uMsg - тип сообщения
;wParam и lParam - по сути, дополнительные данные,
;различные для каждого сообщения
WndProc proc hWin :DWORD, uMsg :DWORD, wParam :DWORD, lParam :DWORD
  ;switch - такой же, как во всех языках. Это макрос MASM32, удобно, не так ли?
  switch uMsg
    ;WM_INITDIALOG отсылается диалогу 1 раз - когда форма загружается
    case WM_INITDIALOG
      ;Давайте установим диалогу иконку "Инфо"
      ;Для этого мы пошлем ему самому сообщение
      ;WM_SETICON с указателем на иконку
      ;которую загрузим функцией LoadIcon
      invoke SendMessage, hWin, WM_SETICON, 1, FUNC(LoadIcon, NULL, IDI_ASTERISK)
      ;FUNC - еще один удобный макрос MASM32
      ;он вызывает функцию и возвращает ее возвращаемое значение :)
 
 
      ;теперь - к обработке нажатий на кнопки
      ;за это ответственно сообщение WM_COMMAND
    case WM_COMMAND
      ;идентификатор кнопки будет в wParam
      ;не верите - вбейте в гугл "WM_COMMAND"
      switch wParam
        ;если нажали на TEST_BTN
        case TEST_BTN
          ;выведем сообщение Hello, World
          invoke MessageBox, hWin, chr$("Hello, world!"), chr$("Test"), 0
          ;здесь chr$("строка") - еще один удобный макрос MASM32
          ;он создает строку в инициализированной секции данных
          ;и возвращает указатель на нее
          ;это эквивалентно записи:
          ;.data
          ;some_name db "Hello, world!",0
          ;...
          ;invoke MessageBox, hWin, offset some_name, ...
 
 
          ;Если нажали Выход
        case EXIT_BTN
          jmp exit_program ;переходим на выход
          ;ДА! Ассемблер - это язык, где никто не будет
          ;ругаться за использование в программе GOTO!
      endsw
 
    ;WM_CLOSE посылается окну при нажатии на крестик или при Alt+F4
    case WM_CLOSE
      exit_program:
      invoke EndDialog, hWin, 0 ;закрываем диалог
    endsw
 
  xor eax,eax ;всегда возвращаем 0
ret
WndProc ENDP

Ну и последнее:

end start

Здесь мы устанавливаем точку входа на метку start, т.е. с нее начнется выполнение программы.

Ну что же, сохраним код как new.asm, закинем в одну папку new.rc, new.asm и xpmanifest.xml и скомпилируем всё следующим bat-файлом:

@echo off
cls
 
REM ну сюда впишите свои пути
SET PATH=C:\Masm32\bin
SET INCLUDE=C:\Masm32\INCLUDE
SET LIB=C:\Masm32\LIB
 
REM компилируем ресурсы
Rc.exe /v %1.rc
 
REM компилируем исходник
ML /nologo -c -coff %1.asm
if errorlevel 1 goto terminate
 
 
REM линкуем всё в exe
REM !!!!!! файл 64stub.exe можно взять отсюда:
REM http://kaimi.ru/2009/08/пакет-для-компиляции-masm32
REM и положить его в папку с батником и проектом
LINK /nologo %1.obj %1.res /SUBSYSTEM:WINDOWS /STUB:64stub.exe /FILEALIGN:512 /VERSION:4.0 /MERGE:.rdata=.text /MERGE:.data=.text /SECTION:.text,EWR /ignore:4078 /RELEASE /BASE:0x400000
 
REM ключей тут много, я описывать их не буду, вот самый примитивный вариант линкования:
rem LINK32 /nologo %1.obj  /SUBSYSTEM:WINDOWS
 
if errorLevel 1 goto terminate
 
echo OK
 
:terminate

После компиляции и линкования получаем программу размером 2.5 кб, которая еще и работает. Ну не прелесть ли?

Надеюсь, эта статья была вам полезна. Хотя о чем это я... Если вы дочитали до этого момента, то явно почерпнули для себя что-то полезное. Надеюсь, вам уже хочется писать свои GUI-программы на ассемблере с использованием MASM32, наполняя их функционалом, ну или хотя бы немного заинтересовала эта тема. В следующей статье я напишу что-нибудь более полезное, чем простой "Hello, world!", и представлю Вашему вниманию.

И последнее. Если после прочтения вы будете находиться в состоянии, подобном этому - не расстраивайтесь, у вас ещё все впереди! :)

Также рекомендую почитать

• MASM32: Немного основ ассемблера (3)
• StepFucker — проходим треки в степмании на АААА (5)
• Библиотека для работы с http (8)
• Пишем плагины для Winamp’а (5)
• Универсальный конвертер текста 1.0 (11)

 Обсудить на форуме